Previous About HAP: Cohomology With Twisted Coefficients next

The cohomology of a group G with coefficients in a ZG-module A is defined as:

 Hn(G,A) = Ker( HomZG(Rn,A) → HomZG(Rn+1,A) ) Image( HomZG(Rn-1,A) → HomZG(Rn,A)

When the abelian group underlying A is free of rank n we can encode A as a group homomorphism A:G → GLn(Z).

When G is a permutation group of degree n the free abelian group Zn admits a canonical G-action defined by

g·(x1, x2, ... , xn) = (xg'(1) , xg'(2) , ... , xg'(n))

where g'=g-1, for g in G and xi in Z. This canonical permutation module A can be constructed for any permutation group G using the HAP command PermToMatrixGroup(). For example:
gap> G:=AlternatingGroup(5);;

gap> A:=PermToMatrixGroup(G,5);
[ (1,2,3,4,5), (3,4,5) ] ->
[ [ [ 0, 1, 0, 0, 0 ], [ 0, 0, 1, 0, 0 ], [ 0, 0, 0, 1, 0 ],
[ 0, 0, 0, 0, 1 ], [ 1, 0, 0, 0, 0 ] ],
[ [ 1, 0, 0, 0, 0 ], [ 0, 1, 0, 0, 0 ], [ 0, 0, 0, 1, 0 ],
[ 0, 0, 0, 0, 1 ], [ 0, 0, 1, 0, 0 ] ] ]
The following commands show that:
• the 6th cohomology of the alternating group G=A5 with coefficients in its 5-dimensional canonical permutation module A is  H6(G,A) = Z2+Z6.
• The 3rd cohomology of the even subgroup B+ of the 5-string Braid group, again with coefficients in the permutation module A (considered as a B+-module via the quotient homomorphism B+ → A5) is H3(B+,A) = Z2+Z6+Z3.
gap> Alt5:=AlternatingGroup(5);;
gap> A:=PermToMatrixGroup(SymmetricGroup(5),5);;
gap> R:=ResolutionFiniteGroup(Alt5,7);;
gap> TR:=HomToIntegralModule(R,A);;
gap> Cohomology(TR,6);
[ 2, 6 ]

gap> D:=[[1,[2,3]],[2,[3,3]],[3,[4,3]]];;
gap> R:=ResolutionArtinGroup(D,10);;
gap> Brd5:=R!.group;; Brd5Gens:=GeneratorsOfGroup(Brd5);;
gap> ImGens:=[Image(A,(1,2)),Image(A,(2,3)),Image(A,(3,4)),Image(A,(4,5))];;
gap> B:=GroupHomomorphismByImages(Brd5,Image(A),Brd5Gens,ImGens);;
gap> EvBrd5:=EvenSubgroup(Brd5);;
gap> S:=ResolutionSubgroup(R,EvBrd5);;
gap> TS:=HomToIntegralModule(S,B);;
gap> Cohomology(TS,3);
[ 2, 6, 0, 0, 0 ]
A group G can act non-trivially on the integers Z. For example, a permutation group G can act on Z according to the formula
g.n= -n    if g is an odd permutation,
g.n=  n    if g is an even permutation.

The following commands show that, with this twisted action of S6 on Z, we have third twisted integral homology  H3(S6,Z)=Z2+Z10 .
gap>  G:=SymmetricGroup(6);;
gap>  R:=ResolutionFiniteGroup(G,4);;
gap>  C:=TensorWithTwistedIntegers(R,SignPerm);;
gap>  Homology(C,3);
[ 2, 10 ]
With the analogous twisted action of S6 on Z5, the following commands show that the twelvth homology  is H12(S6,Z5)=Z5 . (The calculation relies on the fact that Hn(G,Zp)  is equal to its p-primary part Hn(G,Zp)(p)  .)
gap>  G:=SymmetricGroup(6);;
gap>  P:=SylowSubgroup(G,5);;
gap>  R:=ResolutionFiniteGroup(P,15);;
gap>  F:=function(R);return TensorWithTwistedIntegersModP(R,5,SignPerm);end;;
gap>  PrimePartDerivedFunctor(G,R,F,12);
[ 5 ]
 Previous Page Contents Next page