Previous About HAP: Exact Cohomology Coefficient Sequence next

A short exact sequence of ZG-modules
A >--> B -->> C
induces a long exact sequence of cohomology groups
--> Hn(G,A)  --> Hn(G,B) --> Hn(G,C) --> Hn+1(G,A) --> .

The implementation of this sequence is joint work with Daher Al-Baydli.
Consider the symmetric group G=S4 and the sequence
Z/4Z  >----->  Z/8Z ---> Z/2Z

of trivial ZG-modules. We can represent a ZG-module as a GOuterGroup. The following commands use this representation to compute the induced cohomology homomorphism

f: H3(S4,Z/4Z)  ---->  H3(S4,Z/8Z)

and determine that the image of this induced homomorphism has order 8 and that its kernel has order 2.
gap> G:=SymmetricGroup(4);;
gap> x:=(1,2,3,4,5,6,7,8);;
gap> a:=Group(x^2);;
gap> b:=Group(x);;
gap> ahomb:=GroupHomomorphismByFunction(a,b,y->y);;
gap> A:=TrivialGModuleAsGOuterGroup(G,a);;
gap> B:=TrivialGModuleAsGOuterGroup(G,b);;
gap> phi:=GOuterGroupHomomorphism();;
gap> phi!.Source:=A;;
gap> phi!.Target:=B;;
gap> phi!.Mapping:=ahomb;;

gap> Hphi:=CohomologyHomomorphism(phi,3);;

gap> Size(ImageOfGOuterGroupHomomorphism(Hphi));
8

gap> Size(KernelOfGOuterGroupHomomorphism(Hphi));
2
The following commands then compute the homomorphism

H3(S4,Z/8Z)  ---->  H3(S4,Z/2Z)

induced by

Z/4Z  >----->  Z/8Z ---->> Z/2Z .

and determine that the kernel of this homomorphsim has order 8.
gap> bhomc:=NaturalHomomorphismByNormalSubgroup(b,a);
gap> B:=TrivialGModuleAsGOuterGroup(G,b);
gap> C:=TrivialGModuleAsGOuterGroup(G,Image(bhomc));
gap> psi:=GOuterGroupHomomorphism();
gap> psi!.Source:=B;
gap> psi!.Target:=C;
gap> psi!.Mapping:=bhomc;

gap> Hpsi:=CohomologyHomomorphism(psi,3);

gap> Size(KernelOfGOuterGroupHomomorphism(Hpsi));
8
The following commands then compute the connecting homomorphism

H2(S4,Z/2Z)  ---->  H3(S4,Z/4Z)

and determine that the image of this homomorphism has order 2.
gap> delta:=ConnectingCohomologyHomomorphism(psi,2);;
gap> Size(ImageOfGOuterGroupHomomorphism(delta));
2
Note that the various orders are consistent with exactness of the sequence

H2(S4,Z/2Z)  ---->  H3(S4,Z/4Z) ---->  H3(S4,Z/8Z) ---->  H3(S4,Z/2Z)

 Previous Page Contents Next page